Nickles › Forum › Software › Altes Windows: 98, SE, ME und NT

Archiv Altes Windows: 98, SE, ME und NT 16.921 Themen, 62.626 Beiträge

Optionen

Registry komprimieren

Little Walter am 13.02.2004, 00:00 / 2 Antworten / Baumansicht

Wie kompriemiert man die Registry?

The_Bear

Little Walter „Registry komprimieren“

17.02.2004, 00:00 Optionen

Servus!
WOZU?
Wenn du sie weiter verwenden möchtest, dann macht es kein Sinn die einzeln zu komprimieren, sondern nur das ganze Laufwerk (z.B. mit DriveSpace).
Zur Sicherung der Registry startest du regedit.exe, dann markierst du alles (6 Äste oder Eintrag "Arbeitsplatz" ganz oben im Fenster) und gehst dann auf Registry exportieren, gibst einen Dateinamen und speicherst. Danach enthält diese Datei deine komplette Registry und du kannst die Datei dann komrimieren (z.B. mit Winzip). Danach kannst du die Datei importieren um die Registry wiederherzustellen.
The_Bear

Habu

Little Walter „Registry komprimieren“

28.02.2004, 00:00 Optionen

Unter Win95 funktioniert folgendes Script super.

Ab @echo off alles per Copy Paste in eine neue Datei einfügen und als Recomp.bat speichern.
Diese Datei dann unter der Plain DOS starten und warten, das war's.
Vorher mit ERU eine Sicherung der Systemdateien machen ist sicher hilfreich.

Sorry für die fehlenden Umlaute, habe es unter XP eingefügt.
Funktioniert aber trotzdem.

@echo off
rem RegComp.bat, erstellt von Ralf Buschmann
rem EMail: ralf@conactive.com
rem Home : http://www.conactive.com/win95/
cls
echo ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
echo ³RegComp - Komprimieren der Windows95 Registrierdatenbank³
echo ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
echo.
mem /c|find /i "VMM32" >nul
if not errorlevel 1 goto fehler1
set|find /i "WINBOOTDIR" >nul
if errorlevel 1 goto fehler2
ver|find /i "4.00." >nul
if errorlevel 1 goto fehler5
if "%1" == "-r" goto restore
if "%1" == "-R" goto restore
ver|find /i "4.00.1111" >nul
if errorlevel 1 goto fehler3
:memtest
%winbootdir%\
cd %winbootdir%
echo ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
echo.
echo Fr diesen Vorgang wird viel konventioneller Speicher
echo ben”tigt. Wenn der Befehl MEM auf Ihrem System weniger als
echo 600 KByte konventionellen Speicher anzeigt, sollten Sie
echo nicht unbedingt ben”tigte Treiber in der AUTOEXEC.BAT und
echo CONFIG.SYS auskommentieren (REM davor), den PC neu starten
echo und RegComp dann erneut aufrufen. Es wird aber auf jeden
echo Fall ein Backup der Registrierdatenbank erstellt, welches
echo Sie im Fehlerfall durch den Aufruf
echo.
echo RegComp -R
echo.
echo wiederherstellen k”nnen. Die Backupdateien befinden sich
echo im Windows - Verzeichnis als SYSTEM.UNC und USER.UNC.
echo.
choice /c:jn /n "M”chten Sie den Vorgang jetzt starten ? (J,N) "
if errorlevel 2 goto ende
echo.
echo Erstelle Backup der Registrierdatenbank ...
attrib system.dat -h -r -s
attrib user.dat -h -r -s
copy /b /y system.dat system.unc >nul
copy /b /y user.dat user.unc >nul
attrib system.dat +h +r +s
attrib user.dat +h +r +s
echo.
echo ... beendet.
echo.
echo Komprimiere Registrierdatenbank ...
echo.
regedit /e temp.reg
regedit /c temp.reg
del temp.reg
echo.
echo ... beendet.
echo.
echo Ergebnis (*.UNC = alte, *.DAT = neue Gr”áe) :
echo.
dir system.unc|find /i "SYSTEM UNC"
dir /a:h system.dat|find /i "SYSTEM DAT"
echo.
dir user.unc|find /i "USER UNC"
dir /a:h user.dat|find /i "USER DAT"
echo.
echo Starten Sie Windows jetzt neu. Sollte es zu Problemen
echo kommen, so spielen Sie das Backup zurck.
echo.
goto ende

:restore
choice /c:jn /n "M”chten Sie das Backup wirklich wieder herstellen ? (J,N) "
if errorlevel 2 goto ende
%winbootdir%\
cd %winbootdir%
if not exist system.unc goto fehler4
if not exist user.unc goto fehler4
echo.
echo Kopiere Backupdateien ...
attrib system.dat -h -r -s
attrib user.dat -h -r -s
copy /b /y system.unc system.dat >nul
copy /b /y user.unc user.dat >nul
attrib system.dat +h +r +s
attrib user.dat +h +r +s
echo.
echo ... beendet.
goto ende

:fehler1
echo Dieses Programm muá im DOS-Modus ausgefhrt werden !
goto ende

:fehler2
echo Ihr Windows - Verzeichnis konnte nicht gefunden werden.
echo Bitte verwenden Sie den Befehl
echo.
echo SET WINBOOTDIR=[Verzeichnis]
echo.
echo zum Festlegen des Windows - Verzeichnisses.
goto ende

:fehler3
echo Sie benutzen NICHT Windows 95 OSR 2. Laut Microsoft kann
echo es in anderen als dieser Windows-Version zu Problemen bei
echo den hier geplanten Aktionen kommen.
echo.
choice /c:jn /n "M”chten Sie fortsetzten ? (J,N) "
if errorlevel 2 goto ende
goto memtest

:fehler4
echo.
echo Backupdateien nicht gefunden !!!!
echo.

:fehler5
echo.
echo Dieses Programm funktioniert nur mit Windows 95 !
echo.

:ende
echo.