Ich möchte mir meine eigene Tool-CD erstellen.Kann mir einer sagen wie ich unter dos mein eigenes Bootmenü erstellen kann? Ich gab versucht diverse boot-disketten zu mändern (z.b. Win98 Boot-Diskette)aber das ist mir zu kompliziert.
Allgemeines 22.007 Themen, 148.993 Beiträge
Mario32 ottelonie „Wie erstelle ich mein eigenes Bootmenü“
wenn du dir ne TOOL-CD erstellen willst, warum soltest du das Rad neu erfinden wollen/müssen!?
Es gibt das tolle Bart PE!
Das ansich englische Konfig programm nun auch mit DeutscherGUI von PCWELT:
http://www.pcwelt.de/downloads/tools_utilities/system-utilities/108595/index.html
digital-engine Mario32 „Wie erstelle ich mein eigenes Bootmenü“
Das Rad neu erfinden wollte ich eigentlich nicht, aber ich suche nach der Möglichkeit meine eigenen Tools in meinem eigenen Menü zu integrieren. Bei den vorgegebenen Boot-Disketten oder Boot-CD´s wie Bart usw. bin ich halt von den Sachen abhängig die schon vorgegeben sind.Kann aber keine eigenen Tools oder neuere Programme hinzufügen. Gibt es keine Beschreibung für das erstellen von Dos-Menues im Stiele der Win98 Boot-Disk z.B.?
gruß digi
Mario32 digital-engine „Wie erstelle ich mein eigenes Bootmenü“
Bei (...) Boot-CD´s wie Bart (...)Kann aber keine eigenen Tools oder neuere Programme hinzufügen.
DAS ist definitiv nicht richtig! Erstens kannst du es sehr wohl (Schau dir ggfs dazu auch den in meinem Link erwähnten Artikel an), zweitens ist ein Auswahlmenü unter DOS doch relativ simpel zu realisieren (Schau dir ggfs einfach mal den .bat Quelltext einer bootdiskette an, um einen simplen Eindruck zu bekommen: Wenn du mindestens Commodore C64 Basic Kenntnisse hast, verstehst du den Klartext!) und drittens hast du bei DOS das Problem, das "moderne" Dateisysteme wie NTFS was XP standardmäßig verwendet nicht gelesen/geschreiben werden können!
DAS ist definitiv nicht richtig! Erstens kannst du es sehr wohl (Schau dir ggfs dazu auch den in meinem Link erwähnten Artikel an), zweitens ist ein Auswahlmenü unter DOS doch relativ simpel zu realisieren (Schau dir ggfs einfach mal den .bat Quelltext einer bootdiskette an, um einen simplen Eindruck zu bekommen: Wenn du mindestens Commodore C64 Basic Kenntnisse hast, verstehst du den Klartext!) und drittens hast du bei DOS das Problem, das "moderne" Dateisysteme wie NTFS was XP standardmäßig verwendet nicht gelesen/geschreiben werden können!
digital-engine Mario32 „Wie erstelle ich mein eigenes Bootmenü“
Hallo Mario32! Relativ Simpel ist gut! Mit dem editieren der Bat-Dateien oder auch der Config.sys einer Startdiskette ist es nicht getan. Die Strukturen des Auswahlmenues verweisen noch auf etliche andere Dateien die man ebenfalls editieren müsste. Einige davon sind nur mit einem Hex-Editor zu bearbeiten. Ich habe schon mehrfach versucht die Win98-Startdiskette für meine Bedürfnisse umzuschreiben, aber leider sind alle versuche gescheitert. Solltest du das können wäre ich für jeden Tipp dankbar.
gruß digi
Borlander digital-engine „Wie erstelle ich mein eigenes Bootmenü“
meine eigenen Tools in meinem eigenen Menü zu integrieren.
DOS Tools?
Bei den vorgegebenen Boot-Disketten oder Boot-CD´s [...] Kann aber keine eigenen Tools oder neuere Programme hinzufügen.
Schau Dir mal die UltimateBoot CD in der full-Version an, bei der kannst Du mit einem Tool weitere Boot-Images hinzufügen :-)
Gibt es keine Beschreibung für das erstellen von Dos-Menues im Stiele der Win98 Boot-Disk z.B.?
Findest Du u.A. im DOS-Handbuch :-)
Ansonsten such mal im Internet nach [Menu] menuitem config.sys ...
Gruß
Borlander
DOS Tools?
Bei den vorgegebenen Boot-Disketten oder Boot-CD´s [...] Kann aber keine eigenen Tools oder neuere Programme hinzufügen.
Schau Dir mal die UltimateBoot CD in der full-Version an, bei der kannst Du mit einem Tool weitere Boot-Images hinzufügen :-)
Gibt es keine Beschreibung für das erstellen von Dos-Menues im Stiele der Win98 Boot-Disk z.B.?
Findest Du u.A. im DOS-Handbuch :-)
Ansonsten such mal im Internet nach [Menu] menuitem config.sys ...
Gruß
Borlander
digital-engine Borlander „DOS-Menü“
Es geht mir um ein reines DOS-Menü indem ich Dos-tools wie z.B. diverse Festplatten-Diagnose-Tools und ähnliches nach dem Boot-Vorgang starten kann.
gruß Digi
Borlander digital-engine „DOS-Menü“
... lässt sich mit Batch-Dateien realisieren. Eine zur Anzeige eines Menü (=Textdatei ausgeben, den Programmen jeweils einen Buchstaben oder eine Zahl zuordnen) und für jedes Programm eine weitere (die bekommt dann die Zahl oder den Buchstaben für das zugehörige Programm als Namen und kommt ins selbe Verzeichnis). Diese müssen dann erst das Programm starten und anschließend wieder die Batch-Datei zur Menüanzeige aufrufen...
Wenn es um HDD-Diagnose und ähnliches geht schau Dir erst mal die bereits von mir verlinkte UltimateBootCD an, da sind alle wichtigen Tools drauf...
Gruß
Borlander
Mougo ottelonie „Wie erstelle ich mein eigenes Bootmenü“
ich habe dazu ein Tool namens "diskemu" benutzt. Dieses Programm erstellt Dir ein Image das anschließend auf CD / DVD gebrannt werden kann. Vorher musst du von deinen Disketten ein Image erstellen, ich glaube es waren ISO Files. Einfach mal nach dem Programm Googeln.
mfg Mougo
Kelo ottelonie „Wie erstelle ich mein eigenes Bootmenü“
Hallo digital-engine
um in Dos ein Auswahlmenü einzubinden gibt es grundsätzlich zwei Varianten:
1. in der Datei Config.sys
Dieses Menü wird jedes Mal beim Booten aktiviert, es kann aber nach dem Booten nicht mehr aufgerufen werden (ausser die Config.sys wird wieder gestartet, was aber einige Nachteile hat). Diese Möglichkeit eignet sich hauptsächlich dazu, verschiedene Gerätekonfigurationen zu laden.
Beispiel:
Die Punkte MENU, MENUITEM, MENUDEFAULT und und die Sprunganweisungen CDTR01, CDTR02 usw. beachten. Die Sprungmarken können natürlich auch anderst heissen.
Die Befehle unter Common haben nichts mit dem Menü zu tun.
---------------------------------------------------------------------------------------
rem hier koennen schon speichermanager und aehnliches geladen werden
rem menue zur auswahl der cd-rom-treiber
[MENU]
MENUITEM=CDTR01, Mit CD-Rom-Treiber 1 (EIDE und SCSI) starten.
MENUITEM=CDTR02, Mit CD-Rom-Treiber 2 (EIDE und SCSI) starten.
MENUITEM=CDTR03, Mit CD-Rom-Treiber 3 (EIDE und SCSI) starten.
MENUITEM=CDTR04, Mit CD-Rom-Treiber 4 (EIDE und SCSI) starten.
MENUITEM=CDTR05, Mit CD-Rom-Treiber 5 (EIDE und SCSI) starten.
MENUDEFAULT=CDTR01, 10
[COMMON]
rem befehle unter dem punkt common werden immer ausgefuehrt
rem unabhaengig davon was im menu ausgewaehlt wird
rem laden der versionstabelle
DEVICEHIGH=A:\SETVER.EXE
rem laden des bildschirmtreibers
DEVICEHIGH=A:\DISPLAY.SYS CON=(EGA,,1)
rem laden des ansi escape zeichenfolgetreibers
DEVICEHIGH=A:\ANSI.SYS
rem setzt den laufwersbuchstaben des letzten laufwerks auf z
rem ermoeglicht 26 laufwerke
LASTDRIVE=Z
rem legt die anzahl der dateien fest, die in dos
rem gleichzeitig geoeffnet sein koennen
FILES=30
rem legt die groesse des arbeitsspeichers fest, den dos fuer den
rem datentransfer zwischen laufwerken reserviert
rem jeder puffer entspricht 0.5kb, 40 puffer = 20kb
BUFFERS=40
rem legt die groesse des arbeitsspeichers fest, den dos fuer den
rem interrupt stapelspeicher verwendet
STACKS=9,256
rem legt die landesspezifikation auf schweiz fest
COUNTRY=041,850,A:\COUNTRY.SYS
rem laden von dos in den hohen arbeitsspeicher
DOS=HIGH, UMB
[CDTR01]
rem wenn cd-treiber 01 ausgewaehlt ist hier hin springen
rem wenn die aktivierten treiber nicht funktionieren einen anderen auswaehlen
rem laden des eide cd-treibers
DEVICEHIGH=A:\AOATAPI.SYS /D:CD01
rem laden des scsi cd-treibers
DEVICEHIGH=A:\ASPICD.SYS /D:CD01
[CDTR02]
rem wenn cd-treiber 02 ausgewaehlt ist hier hin springen
rem wenn die aktivierten treiber nicht funktionieren einen anderen auswaehlen
rem laden des eide cd-treibers
DEVICEHIGH=A:\CDDRVEDI.SYS /D:CD01
rem laden des scsi cd-treibers
DEVICEHIGH=A:\ASPI2DOS.SYS /D:CD01
[CDTR03]
rem wenn cd-treiber 03 ausgewaehlt ist hier hin springen
rem wenn die aktivierten treiber nicht funktionieren einen anderen auswaehlen
rem laden des eide cd-treibers
DEVICEHIGH=A:\CPQIDECD.SYS /D:CD01
rem laden des scsi cd-treibers
DEVICEHIGH=A:\ASPI4DOS.SYS /D:CD01
[CDTR04]
rem wenn cd-treiber 04 ausgewaehlt ist hier hin springen
rem wenn die aktivierten treiber nicht funktionieren einen anderen auswaehlen
rem laden des eide cd-treibers
DEVICE=A:\CD2.SYS /D:CD01
rem laden des scsi cd-treibers
DEVICE=A:\ASPI8DOS.SYS /D:CD01
[CDTR05]
rem wenn cd-treiber 05 ausgewaehlt ist hier hin springen
rem wenn die aktivierten treiber nicht funktionieren einen anderen auswaehlen
rem laden des eide cd-treibers
DEVICE=A:\CD3.SYS /D:CD01
rem laden des scsi cd-treibers
DEVICE=A:\ASPI8U2.SYS /D:CD01
---------------------------------------------------------------------------------------
2. über eine Batch-Datei
Das Menu in der Batch-Datei kann jederzeit durch Eingabe des Namens der Batch-Datei aufgerufen werden (der Name der Batch kann 1-8 Zeichen aufweisen und muss die Endung .bat haben). Es können allerdings keine Gerätetreiber, welche zwingend in der Config.sys oder Autoexec.bat geladen werden müssen, geladen werden. Diese Möglichkeit eignet sich hauptsächlich dazu, verschiedene Programme einfach aus einem Menü heraus aufzurufen (wahrscheinlich das was Du suchst).
Beispiel:
Beachten: Sprungmarken in Batch-Dateien beginnen mit einem :
Die Errorlevels müssen von der grösseren Zahl zur kleineren Zahl abgefragt werden.
---------------------------------------------------------------------------------------
rem stapelverarbeitungsprogramm zur auswahl von vorhandenen programmen
@ECHO OFF
CLS
ECHO Waehlen Sie das Programm, welches Sie starten moechten:
ECHO =======================================================
rem folgende programme stehen zur wahl
ECHO:
ECHO A fuer Ace 2.0 Packer starten (ACE.EXE)
ECHO B fuer Arrowsoft Assembler starten (ASM.EXE)
ECHO C fuer CT's Bios-Test starten (CTBIOS.EXE)
ECHO D fuer CT's Ram-Test starten (CTRAM51.EXE)
ECHO E fuer Diagnostik starten (MSD.EXE)
ECHO F fuer Diskeditor starten (DISKEDIT.EXE)
ECHO G fuer Disk Imager 1.1 starten (DI.EXE)
ECHO H fuer Dosshell starten (DOSSHELL.EXE)
ECHO I fuer Drive Image Pro 4.0 starten (PQDI.EXE)
ECHO J fuer Easy Recovery Pro 5.10 starten (ERDOS.EXE)
ECHO K fuer Editor starten (EDIT.COM)
ECHO L fuer F-Prot 3.09c Antivirus starten (F-PROT.EXE)
ECHO M fuer Ghost 2001 PE starten (GHOSTPE.EXE)
ECHO N fuer Norton Commander 5.5 starten (NC.EXE)
ECHO O fuer Partition Magic 6.0 starten (PQMAGIC.EXE)
ECHO P fuer Qbasic starten (QBASIC.EXE)
ECHO Q fuer Volkov Commander 4.05 starten (VC.COM)
ECHO:
ECHO R fuer Zurueck zur Eigabeaufforderung
ECHO:
CHOICE /c:abcdefghijklmnopqr /N Programm durch Eingabe des Buchstabens waehlen:
IF ERRORLEVEL 18 GOTO PROMPT
IF ERRORLEVEL 17 GOTO VC
IF ERRORLEVEL 16 GOTO QBASIC
IF ERRORLEVEL 15 GOTO PM
IF ERRORLEVEL 14 GOTO NC
IF ERRORLEVEL 13 GOTO GHOSTPE
IF ERRORLEVEL 12 GOTO FPROT
IF ERRORLEVEL 11 GOTO EDIT
IF ERRORLEVEL 10 GOTO EREC
IF ERRORLEVEL 9 GOTO PQDI
IF ERRORLEVEL 8 GOTO DOSSHELL
IF ERRORLEVEL 7 GOTO DI
IF ERRORLEVEL 6 GOTO DED
IF ERRORLEVEL 5 GOTO MSD
IF ERRORLEVEL 4 GOTO CR
IF ERRORLEVEL 3 GOTO CB
IF ERRORLEVEL 2 GOTO ASM
IF ERRORLEVEL 1 GOTO ACE
:ACE
CLS
S:\P\ACE\ACE.EXE
GOTO END
:ASM
CLS
S:\P\ASM\ASM.EXE
GOTO END
:CB
CLS
S:\P\CB\CTBIOS.EXE
GOTO END
:CR
CLS
S:\P\CR\CTRAM51.EXE
GOTO END
:MSD
CLS
S:\DOS\MSD.EXE
GOTO END
:DED
CLS
S:\P\DED\DISKEDIT.EXE
GOTO END
:DI
CLS
S:\P\DI\DI.EXE
GOTO END
:DOSSHELL
CLS
S:\DOS\DOSSHELL.EXE
GOTO END
:PQDI
CLS
S:\P\PQDI\PQDI.EXE
GOTO END
:EREC
CLS
S:\P\EREC\ERDOS.EXE
GOTO END
:EDIT
CLS
S:\DOS\EDIT.COM
GOTO END
:FPROT
CLS
S:\P\FPR\F-PROT.EXE
GOTO END
:GHOSTPE
CLS
S:\P\GHO\GHOSTPE.EXE
GOTO END
:NC
CLS
S:\P\NC\NC.EXE
CLS
GOTO END
:PM
CLS
S:\P\PM\PQMAGIC.EXE
GOTO END
:QBASIC
CLS
S:\DOS\QBASIC.EXE
GOTO END
:VC
CLS
S:\P\VC\VC.COM
CLS
GOTO END
:PROMPT
CLS
GOTO END
:END
---------------------------------------------------------------------------------------
Diese beiden Menüs habe ich einmal für eine Boot-CD erstellt.
Ich hoffe, das ist das, was Du suchst. Bei Fragen oder für notwendige Anpassungen einfach wieder Fragen. Nebenbei, die Dateien können mit einem Texteditor bearbeitet und abgespeichert werden, der (Windows-) Editor genügt vollauf.
Liebe Grüsse Kelo
